1 SYS1400,"SCAUG",49152:SYS1258,49152,56832,2:SYS1400,"SCMIL",49152:SYS1258,49152,56320,2:SYS1400,"AUG",49152:SYS1258,49152,54784,6:SYS1400,"MILI",49152:SYS1258,49152,53248,6:SYS1400,"KARTE2",57344:SYS1400,"ZSMILI2",49152:SYS1400,"SCHLACHTH",40960:SYS1400,"SPR1",65408
2 POKE53265,PEEK(53265)OR16:PRINT"[147][144]":DIMMA(16),SE(16),RE(16),JR(16),ZM(16),KR(16),GR(16),A$(16):HP(1)=2:HP(2)=14:HP(3)=13:HP(4)=9:SI=54272:M=1:JA=305:KP=5:MP=50:ZS=4:DIMPO(16),SN(16),BN(16),IS(16),SC(4),ZP(4),M$(12),AG(16),AB(16),IB(16)
3 WS$(1)=" WENN DU IN DEN KRIEG ZIEHST, WIRST DU   EIN GROSSES HEER VERNICHTEN":WS$(2)=" DU WIRST EINEN GROSSEN SIEG ERLEBEN ":WS$(3)=" DIE SCHLACHT WIRD G]NSTIG VERLAUFEN ":WS$(4)=" ES WERDEN VIELE TAPFERE M[NNER          STERBEN"
4 FORI=1TO4:ZP(I)=4:KO(I)=200000:EX(I)=1:NEXT:POKE53280,1:DIMZH(16),N$(4):DIMEP(16),BV(16),LE(16),SO(16),BO(16),K(16),GB(16),BW(16),FB(16),ZB(16):DIMSV(16),MO(16),BE(16),A(6,16),BL(16),BS(16),BB(16),BK(16),NP$(16),ZG(16)
5 OPEN2,8,2,"NAMES,S,R":FORI=1TO4:INPUT#2,N$(I):NEXT:FORI=1TO16:INPUT#2,NP$(I):INPUT#2,BW(I):INPUT#2,FB(I):INPUT#2,ZB(I):INPUT#2,ZG(I):INPUT#2,ZH(I):NEXT:CLOSE2:FORI=1TO16:PO(I)=5000:SN(I)=15:IS(I)=5:KR(I)=10:NEXT:OPEN2,8,2,"DATA1,S,R":FORI=1TO16:INPUT#2,EP(I):INPUT#2,BV(I):INPUT#2,LE(I)
6 INPUT#2,SO(I):INPUT#2,BO(I):INPUT#2,K(I):INPUT#2,GB(I):INPUT#2,SV(I):INPUT#2,MO(I):INPUT#2,BE(I):NEXT:CLOSE2:OPEN2,8,2,"DATA2,S,R":INPUT#2,SP:INPUT#2,KP(1):INPUT#2,KP(2):INPUT#2,KP(3):INPUT#2,KP(4):CLOSE2:GOSUB24:M$(1)="JANUAR":M$(2)="FEBRUAR":M$(3)="M[RZ":M$(4)="APRIL":M$(5)="MAI"
7 M$(6)="JUNI":M$(7)="JULI":M$(8)="AUGUST":M$(9)="SEPTEMBER":M$(10)="OKTOBER"
8 SYS1659:YK=80:Y=4:POKE53280,1:GOTO13
9 IFPEEK(56320)=125ANDYK<80THENYK=YK+10:GOSUB393:Y=Y+1
10 IFPEEK(56320)=126ANDYK>50THENYK=YK-10:GOSUB393:Y=Y-1
11 POKE53249,YK:IFPEEK(56320)=111THENGOSUB393:ONYGOTO23,194,363,376:GOTO9
12 GOTO9
13 FORI=1TO16:POKE1799+I,EP(I):NEXT:FORI=1TO8:POKE64775+I,PEEK(1872+8*SP+I):NEXT:SYS1072:GOTO9
14 PRINT"[147] VON WELCHER PROVINZ M\CHTEN SIE":PRINT"  EINE MILIT[R-]BERSICHT ?":GOSUB423:PRINT"  MILIT[R-]BERSICHT DER PROVINZ":PRINT"   ";NP$(P);TAB(27);M$(M);JA:PRINT"  LEGION[RE :";TAB(23);LE(P):PRINT"  S\LDNER :";TAB(23);SO(P)
15 PRINT"  BOGENSCH]TZEN :";TAB(23);BO(P):PRINT"  KATAPULTE :";TAB(23);K(P):PRINT"  STIMMUNG IM MILIT[R :";TAB(24);MO$(MO(P)):PRINT"  GRENZBEFESTIGUNG :";TAB(24);GB$(GB(P)):GOTO77
16 PRINT"  WOLLEN SIE DEN P\BEL ALLER IHRER":GK=0:J$="J":PRINT"  PROVINZEN AUF EINMAL VERSORGEN ? ";J$;:GOSUB408:PRINT:IFJ$="N"THEN196
17 FORI=1TO16:IFEP(I)<>SPTHEN19
18 GK=GK+PO(I)
19 NEXT:IFGK>KO(SP)THENPRINT"  SIE BESITZEN NICHT GEN]GEND KORN !":WAIT56320,16,16:GOTO196
20 KO(SP)=KO(SP)-GK:PP=1:FORI=1TO16:IFEP(I)<>SPTHEN22
21 BN(I)=PO(I)
22 NEXT:GOTO195
23 SYS1624:SYS1258,53248,49664,6:GOTO29
24 MO$(0)="GANZ MIES":MO$(1)="SEHR SCHLECHT":MO$(2)="SCHLECHT":MO$(3)="SEHR UNZUFRIEDEN":MO$(4)="UNZUFRIEDEN":MO$(5)="NORMAL":MO$(6)="ZUFRIEDEN":MO$(7)="ZIEMLICH GUT":MO$(8)="GUT":MO$(9)="SEHR GUT":MO$(10)="BEGEISTERT"
25 M$(11)="NOVEMBER":M$(12)="DEZEMBER":A(1,1)=2:A(1,2)=1:A(2,2)=3:A(3,2)=15:A(4,2)=14:A(1,3)=2:A(2,3)=4:A(1,4)=3:A(2,4)=5:A(1,5)=4:A(2,5)=6:A(2,1)=15:A(1,6)=5:A(2,6)=7:A(1,7)=6:A(2,7)=8:A(3,7)=14:A(1,8)=7:A(2,8)=9:A(1,9)=8:A(2,9)=10:A(3,9)=11
26 A(1,10)=9:A(2,10)=11:A(3,10)=12:A(1,11)=10:A(2,11)=12:A(3,11)=13:A(1,12)=10:A(2,12)=11:A(3,12)=13:A(1,13)=12:A(2,13)=11:A(3,13)=14:A(4,13)=16:A(1,14)=13:A(2,14)=16:A(3,14)=15:A(4,14)=2:A(5,14)=7:A(1,15)=2:A(2,15)=16:A(3,15)=14
27 A(1,16)=15:A(2,16)=14:A(3,16)=13:A(4,16)=2:A(2,1)=15:A(4,15)=1:GB$(0)="NICHT VORH.":GB$(1)="SEHR SCHLECHT":GB$(2)="SCHLECHT":HZ$(1)="AUG":HS$(1)="SCAUG":HZ$(2)="MEDI":HS$(2)="SCMED"
28 GB$(3)="NICHT AUSREICHEND":GB$(4)="KAUM AUSREICHEND":GB$(5)="AUSREICHEND":HZ$(3)="SIRMI":HS$(3)="SCSIRM":HZ$(4)="NICO":HS$(4)="SCNIC":GB$(6)="BEFRIEDIGEND":GB$(7)="ZIEMLICH GUT":GB$(8)="GUT":GB$(9)="SEHR GUT":GB$(10)="SUPER":RETURN
29 SYS1464,56320
30 POKE53281,1:POKE53280,6:PRINT"[144]";:SYS1200:PRINT"        MILIT[R":PRINTTAB(2);" SIE RUFEN IHREN":PRINT"   OBERSTEN FELDHERRN.":PRINT"   DIESER ERSCHEINT":PRINTTAB(2);" SOGLEICH IN IHREM":PRINTTAB(2);" PALAST UND RUFT :":PRINT:PRINT" AVE, CAESAR ";N$(SP);"!":PRINT:PRINT:PRINT" WOLLEN SIE":PRINT
31 PRINT"  ARMEEST[RKE VER[NDERN":PRINT"  TRUPPEN BEWEGEN":PRINT"  GRENZEN BEFESTIGEN":PRINT"  ANGREIFEN":PRINT"  MILIT[R-]BERSICHT":PRINT" _^MENUE":I=21:J=16:GOSUB449:A=PEEK(214)-15:ONAGOTO32,63,78,84,14,8
32 PRINT"[147]   ARMEEST[RKE":PRINT:PRINT"  SIE HABEN FOLGENDE ":PRINT"  M\GLICHKEITEN :":PRINT"                     ":PRINT"  LEGION[RE REKRUTIEREN":PRINT"  S\LDNER ANWERBEN     ":PRINT"  SOLDATEN ENTLASSEN":PRINT"  BOGENSCH]TZEN AUSBILDEN":PRINT"  KATAPULTE KAUFEN":PRINT"  MORAL STEIGERN"
33 PRINT"  KARTE BETRACHTEN":PRINT" _^MENUE":PRINT:PRINT"  IHR KAPITAL BETR[GT":PRINT"  ";KP(SP);"AUREI !":PRINT"[145][145][145]";:I=14:J=7:GOSUB449:ON(PEEK(214)-6)GOTO34,40,44,51,180,56,60,30
34 PRINT"":PRINT"IN WELCHER PROVINZ WOLLEN SIE ":PRINT"    REKRUTIEREN ?";:GOSUB423:PRINT"[145][145][145][145][145]":PRINT" WIEVIELE LEGION[RE WOLLEN SIE":PRINT"    REKRUTIEREN ?";:GOSUB398:S=SL:IFS=0THEN32
35 IFRE(P)+SL>5000THENPRINT"  KEINE DERARTIGE REKRUTIERUNG M\GLICH !":GOTO38
36 IFGR(P)+S>0.2*BV(P)THENPRINT"  KEINE DERARTIGE REKRUTIERUNG M\GLICH !":GOTO38
37 GOTO39
38 WAIT56320,16,16:PRINT"":GOTO32
39 LE(P)=LE(P)+S:RE(P)=RE(P)+SL:GR(P)=GR(P)+SL:MO(P)=INT((MO(P)*(LE(P)+SO(P)+BO(P)-SL)+5*SL)/(LE(P)+SO(P)+BO(P))):PRINT" IN DIESER PROVINZ BEFINDEN SICH NUN":PRINT"   ";LE(P);" LEGION[RE !":WAIT56320,16,16:GOTO32
40 PRINT"":PRINT"F]R WELCHE PROVINZ WOLLEN SIE ":PRINT"    ANWERBEN ?";:GOSUB423:PRINT"[145][145][145]":PRINT" WIEVIELE S\LDNER WOLLEN SIE F]R ":PRINT" 4 AUREI/KOPF ANWERBEN";:GOSUB398:S=SL:IFINT(KP(SP)-S*4+.5)<0THEN29
41 IFS=0THEN43
42 SO(P)=SO(P)+S:KP(SP)=INT(KP(SP)-S*4+.5):MO(P)=INT((MO(P)*(LE(P)+SO(P)+BO(P)-SL)+4*S)/(LE(P)+SO(P)+BO(P)))
43 PRINT" IN DIESER PROVINZ BEFINDEN SICH NUN":PRINT"   ";SO(P);" S\LDNER !":WAIT56320,16,16:GOTO32
44 PRINT"":PRINT"IN WELCHER PROVINZ WOLLEN SIE ":PRINT" SOLDATEN ENTLASSEN ?";:GOSUB423:PRINT"[145][145][145]":PRINT" WOLLEN SIE                       ":PRINT"   S\LDNER ODER                        ":PRINT" _ LEGION[RE                       ":PRINT" ENTLASSEN ?[145]":A=2:GOTO181
45 POKE781,19:SYS59903:POKE781,20:SYS59903:PRINT"[145][145]":PRINT" WIEVIELE SOLDATEN WOLLEN SIE          ":PRINT"  ENTLASSEN ?";:GOSUB398:POKE781,23:SYS59903:POKE781,22:SYS59903:IFA=1THEN48
46 IFSL>LE(P)THEN32
47 LE(P)=LE(P)-SL:GOTO50
48 IFSL>SO(P)THEN32
49 SO(P)=SO(P)-SL
50 PRINT"[145][145] IN DIESER PROVINZ BEFINDEN SICH NUN ":PRINTSO(P);"S\LDNER UND";LE(P);"LEGION[RE !     ":WAIT56320,16,16:GOTO32
51 PRINT"":PRINT"IN WELCHER PROVINZ WOLLEN SIE ":PRINT" BOGENSCH]TZEN AUSBILDEN ?";:GOSUB423:PRINT"[145][145][145]":PRINT" WIEVIELE BOGENSCH]TZEN WOLLEN SIE ZU":PRINT" 50 AUREI/KOPF AUSBILDEN ?";:GOSUB398:IFSL*50>KP(SP)THEN32
52 BO(P)=BO(P)+SL:KP(SP)=KP(SP)-SL*50:MO(P)=INT((MO(P)*(LE(P)+SO(P)+BO(P)-SL)+5*SL)/(LE(P)+SO(P)+BO(P))):GOTO55
53 PRINT"[145][145][145]":PRINT" WIEVIELE KATAPULTE WOLLEN SIE ZU":PRINT" 100 AUREI/ST]CK KAUFEN ?";:GOSUB398:IFSL*100>KP(SP)THEN32
54 K(P)=K(P)+SL:KP(SP)=KP(SP)-SL*100
55 PRINT" IN DIESER PROVINZ BEFINDEN SICH NUN":PRINT" ";BO(P);"BOGENSCH]TZEN UND";K(P);"KATAPULTE !":WAIT56320,16,16:GOTO32
56 PRINT"":PRINT"IN WELCHER PROVINZ WOLLEN SIE ":PRINT" DIE MORAL STEIGERN ?";:GOSUB423:PRINT"[145][145][145][145] DIE MORAL HIER IST ";MO$(MO(P)):PRINT" WIEVIEL GELD WOLLEN SIE F]R DIE ARMEE":PRINT"  ZUS[TZLICH AUSGEBEN";:GOSUB398:POKE781,18:SYS59903:IFKP(SP)-SL<0THEN32
57 ZM(P)=ZM(P)+SL:XX=LE(P)+SO(P)+BO(P):IFXX=0THENZM(P)=0:GOTO59
58 MO(P)=MO(P)+INT(2*ZM(P)/XX):KP(SP)=KP(SP)-SL:ZM(P)=XX*(2*ZM(P)/XX-INT(2*ZM(P)/XX)):IFMO(P)>10THENMO(P)=10
59 PRINT" [145][145]DIE MORAL DER TRUPPE IST JETZT        ":POKE781,22:SYS59903:POKE781,21:SYS59903:PRINT"  ";MO$(MO(P)):WAIT56320,16,16:GOTO32
60 SYS1024:POKE53272,56
61 IFPEEK(56320)<>111THEN61
62 POKE53272,48:POKE53265,PEEK(53265)AND223:GOTO32
63 PRINT"":SYS1200:PRINT" AUS WELCHER PROVINZ WOLLEN SIE ":PRINT"  TRUPPEN ZIEHEN ?";:GOSUB423:P1=P:PRINT" IN WELCHE PROVINZ WOLLEN SIE":PRINT"   TRUPPEN ZIEHEN ?";:GOSUB423:P2=P:X=1
64 IFP1=A(X,P2)THEN67
65 IFA(X,P2)=0THEN30
66 X=X+1:GOTO64
67 T=17:S=29:PRINT"[147]":PRINTTAB(T);LEFT$(NP$(P1),10);TAB(S);LEFT$(NP$(P2),10):PRINTTAB(10);" ---------------------------":PRINT" LEGION[RE :";TAB(T);LE(P1);TAB(S);LE(P2):PRINT" S\LDNER :";TAB(T);SO(P1);TAB(S);SO(P2):PRINT" BOGENSCH]TZEN :";TAB(T);BO(P1);TAB(S);BO(P2):PRINT" KATAPULTE :";TAB(T);K(P1);TAB(S);K(P2)
68 PRINT" WIEVIELE LEGION[RE WOLLEN SIE NACH ":PRINT"  ";LEFT$(NP$(P2),10);" ZIEHEN ?";:GOSUB398:IFSL>LE(P1)THENPRINT" UNM\GLICH ":GOTO77
69 IFSL>LE(P1)-BL(P1)THENPRINT" UNM\GLICH":GOTO77
70 LE(P1)=LE(P1)-SL:LE(P2)=LE(P2)+SL:BL(P2)=BL(P2)+SL:PRINT" WIEVIELE S\LDNER WOLLEN SIE NACH ":PRINT"  ";LEFT$(NP$(P2),10);" ZIEHEN ?";:GOSUB398:IFSL>SO(P1)THENPRINT" UNM\GLICH ":GOTO77
71 IFSL>SO(P1)-BS(P1)THENPRINT" UNM\GLICH":GOTO77
72 SO(P1)=SO(P1)-SL:SO(P2)=SO(P2)+SL:BS(P2)=BS(P2)+SL:PRINT" WIEVIELE SCH]TZEN WOLLEN SIE NACH ":PRINT"  ";LEFT$(NP$(P2),10);" ZIEHEN ?";:GOSUB398:IFSL>BO(P1)THENPRINT" UNM\GLICH ":GOTO77
73 IFSL>BO(P1)-BB(P1)THENPRINT" UNM\GLICH":GOTO77
74 BO(P1)=BO(P1)-SL:BO(P2)=BO(P2)+SL:BB(P2)=BB(P2)+SL:PRINT" WIEVIELE KATAPULTE WOLLEN SIE NACH ":PRINT"  ";LEFT$(NP$(P2),10);" ZIEHEN ?";:GOSUB398:IFSL>K(P1)THENPRINT" UNM\GLICH ":GOTO77
75 IFSL>K(P1)-BK(P1)THENPRINT" UNM\GLICH":GOTO77
76 K(P1)=K(P1)-SL:K(P2)=K(P2)+SL:BK(P2)=BK(P2)+SL
77 WAIT56320,16,16:PRINT"[147]":GOTO30
78 PRINT"":SYS1200:PRINT" IN WELCHER PROVINZ WOLLEN SIE DIE":PRINT"  GRENZEN BEFESTIGEN ?";:GOSUB423:PRINT"[145][145][145]":PRINT"DIE GRENZBEFESTIGUNG IN DIESER PROVINZ":PRINT" IST ";GB$(GB(P));:FORT=1TO30-LEN(GB$(GB(P))):PRINT" ";:NEXT:PRINT:PRINT" WIEVIEL GELD WOLLEN SIE F]R NEUE     "
79 PRINT" ANLAGEN AUSGEBEN ?";:GOSUB398:PRINT:IFSL>KP(SP)THEN30
80 GB(P)=INT(GB(P)+SL/2000+.5):KP(SP)=KP(SP)-SL:IFGB(P)>10THENGB(P)=10
81 PRINT"  DIE GRENZBEFESTIGUNG IST NUN         ":PRINT"   ";GB$(GB(P));" !":WAIT56320,16,16:GOTO30
82 PRINT:PRINT" CAESAR ";N$(EP(P1));", NEHMEN SIE ":J$="J":PRINT"  DIE BESTECHUNG AN ?";J$;:GOSUB408:PRINT:PRINT:IFJ$="N"THEN114
83 KP(SP)=KP(SP)+SL:KP(EP(P2))=KP(EP(P2))-SL:GOTO29
84 IFJA=308ANDM=1THEN30
85 PRINT"[147] WEN WOLLEN SIE ANGREIFEN ?":S=0:N=0:G=0:A=2:AN=0:V=0:SE=0:PRINT:PRINT"   BARBAREN ":PRINT"  _FEINDLICHE PROVINZ"
86 IFPEEK(56320)=126ANDA=2THENA=1:PRINT"[145][145]  _":PRINT"   ":GOSUB393
87 IFPEEK(56320)=125ANDA=1THENA=2:PRINT"[145][145]   ":PRINT"  _":GOSUB393
88 IFPEEK(56320)=111THENGOSUB393:GOTO90
89 GOTO86
90 IFA=2THEN177
91 PRINT:PRINT"  AUS WELCHER PROVINZ WOLLEN SIE ":PRINT"   ANGREIFEN":GOSUB423:P1=P:GOSUB378:KK=3*EL+2*ES+4*EB+20*EK:IFKK=0THEN29
92 PRINT"   DER FELDZUG L[UFT !!!":FORX=1TO2000:NEXT:KK=KK/100000*(15+MO(P))/20:Y=INT(RND(0)*2)+1:KK=KK*Y:IFKK<.2THENA=1:N=-2:G=-2:GOTO96
93 IFKK<.4THENA=2:N=-1:GOTO96
94 IFKK<.8THENA=3:GOTO96
95 A=4:N=2:S=1
96 GOSUB394:PRINT"[147]    DAS ERGEBNIS IHRES FELDZUGES":PRINT:PRINT:FI$="BARBAR"+STR$(A):OPEN2,8,2,FI$+",S,R":INPUT#2,AZ:FORT=1TO2*AZ-1:GET#2,A$:IFA$=CHR$(13)THENNEXT
97 PRINTA$;:NEXT:CLOSE2:PRINT:PRINT:IFKK<0.2THENY=1:GOTO101
98 IFKK<0.4THENY=RND(0)*.2+.5:GOTO101
99 IFKK<0.8THENY=RND(0)*.2+.2:GOTO101
100 Y=RND(0)*.1
101 B=INT(10000*KK/2*(RND(0)*2+1)):VL%=Y*EL:VS%=Y*ES:VB%=Y*EB:VK%=Y*EK:PRINT"  VERLUSTLISTE: ":PRINT:PRINT" LEGION[RE :";VL%:PRINT" S\LDNER :";VS%:PRINT" SCH]TZEN :";VB%:PRINT" KATAPULTE :";VK%:PRINT:PRINT:PRINT" SIE ERBEUTETEN ";B;" AUREI !"
102 LE(P)=LE(P)-VL%:SO(P)=SO(P)-VS%:BO(P)=BO(P)-VB%:K(P)=K(P)-VK%:KP(SP)=KP(SP)+B:MO(P)=MO(P)+N:GB(P)=GB(P)+G:SV(P)=SV(P)+S:IFMO(P)>10THENMO(P)=10
103 IFMO(P)<0THENMO(P)=0
104 IFGB(P)<0THENGB(P)=0
105 IFSV(P)>10THENSV(P)=10
106 GOTO77
107 PRINT"[147]  VON WELCHER PROVINZ AUS WOLLEN SIE":PRINT"   ANGREIFEN ?":GOSUB423:P1=P:PRINT:PRINT:PRINT" WELCHE PROVINZ WOLLEN SIE":PRINT"   ANGREIFEN ?":GOSUB436:P2=P:X=1:K1=0:K2=0
108 IFP1=A(X,P2)THEN111
109 IFA(X,P2)=0THEN174
110 X=X+1:GOTO108
111 IFEP(P2)=0THEN114
112 PRINT:PRINT" CAESAR ";N$(EP(P2));", WOLLEN SIE ":J$="J":PRINT"  DEN ANGREIFER BESTECHEN ? ";J$;:GOSUB408:PRINT:PRINT:IFJ$="N"THEN114
113 PRINT" WIEVIEL GELD WOLLEN SIE ":PRINT" IHM GEBEN ?";:GOSUB398:IFSL<=KP(EP(P2))THEN82
114 GOSUB378:K1=3*EL+2*ES+4*EB+25*EK:K2=3*LE(P2)+2*SO(P2)+4*BO(P2)+25*K(P2):IFK1=0THEN77
115 LE(P1)=LE(P1)-EL:SO(P1)=SO(P1)-ES:BO(P1)=BO(P1)-EB:K(P1)=K(P1)-EK:IFK2=0THEN293
116 K1=K1/100000:K2=K2/100000:SYS1966:SYS1333:SYS1701:XY=500:POKE53272,56:POKE53265,PEEK(53265)OR32:SYS1200
117 X$=STR$(EL):I=2:POKE250,128:POKE251,244:IFPEEK(56320)=111THEN185
118 A$=MID$(X$,I,1):A=VAL(A$):POKE2032,A*8:SYS1600:IFPEEK(56320)=111THEN185
119 I=I+1:POKE250,PEEK(250)+8:IFI=LEN(X$)+1THEN121
120 GOTO118
121 X$=STR$(LE(P2)):I=2:POKE250,216:POKE251,244
122 A$=MID$(X$,I,1):A=VAL(A$):POKE2032,A*8:SYS1600:I=I+1:GOSUB175:IFI=LEN(X$)+1THEN124
123 GOTO122
124 X$=STR$(ES):I=2:POKE250,193:POKE251,245:IFPEEK(56320)=111THEN185
125 A$=MID$(X$,I,1):A=VAL(A$):POKE2032,A*8:SYS1600:I=I+1:GOSUB175:IFI=LEN(X$)+1THEN127
126 GOTO125
127 X$=STR$(SO(P2)):I=2:POKE250,25:POKE251,246:IFPEEK(56320)=111THEN185
128 A$=MID$(X$,I,1):A=VAL(A$):POKE2032,A*8:SYS1600:I=I+1:POKE250,PEEK(250)+8:IFI=LEN(X$)+1THEN130
129 GOTO128
130 X$=STR$(EB):I=2:POKE250,1:POKE251,247:IFPEEK(56320)=111THEN185
131 A$=MID$(X$,I,1):A=VAL(A$):POKE2032,A*8:SYS1600:I=I+1:POKE250,PEEK(250)+8:IFI=LEN(X$)+1THEN133
132 GOTO131
133 X$=STR$(BO(P2)):I=2:POKE250,89:POKE251,247:IFPEEK(56320)=111THEN185
134 A$=MID$(X$,I,1):A=VAL(A$):POKE2032,A*8:SYS1600:I=I+1:POKE250,PEEK(250)+8:IFI=LEN(X$)+1THEN136
135 GOTO134
136 X$=STR$(EK):I=2:POKE250,65:POKE251,248:IFPEEK(56320)=111THEN185
137 A$=MID$(X$,I,1):A=VAL(A$):POKE2032,A*8:SYS1600:I=I+1:POKE250,PEEK(250)+8:IFI=LEN(X$)+1THEN139
138 GOTO137
139 X$=STR$(K(P2)):I=2:POKE250,153:POKE251,248
140 A$=MID$(X$,I,1):A=VAL(A$):POKE2032,A*8:SYS1600:I=I+1:POKE250,PEEK(250)+8:IFI=LEN(X$)+1THEN142
141 GOTO140
142 IFAN=4THEN171
143 IFV=4THEN160
144 AN=0:V=0:EL=INT(EL-((RND(0)*2+1)/2*XY*K2/K1*(GB(P2)+1)/3)):LE(P2)=INT(LE(P2)-((RND(0)+1)/2*XY*K1/K2)):IFEL<=0THENEL=0:AN=AN+1
145 IFLE(P2)<=0THENLE(P2)=0:V=V+1
146 IFPEEK(56320)=111THEN185
147 IFLE(P2)<=0THENLE(P2)=0
148 ES=INT(ES-((RND(0)*2+1)/2*XY*K2/K1*(GB(P2)+1)/3)):IFPEEK(56320)=111THEN185
149 SO(P2)=INT(SO(P2)-((RND(0)+1)/2*XY*K1/K2)):IFES<=0THENES=0:AN=AN+1
150 IFSO(P2)<=0THENSO(P2)=0:V=V+1
151 EB=INT(EB-((RND(0)*2+1)/50*XY*K2/K1*(GB(P2)+1)/3)):IFPEEK(56320)=111THEN185
152 BO(P2)=INT(BO(P2)-((RND(0)+1)/50*XY*K1/K2)):IFEB<=0THENEB=0:AN=AN+1
153 IFBO(P2)<=0THENBO(P2)=0:V=V+1
154 IFPEEK(56320)=111THEN185
155 EK=INT(EK-((RND(0)*2+1)/100*XY*K2/K1*(GB(P2)+1)/3)):IFPEEK(56320)=111THEN185
156 K(P2)=INT(K(P2)-((RND(0)+1)/100*XY*K1/K2)):IFEK<=0THENEK=0:AN=AN+1
157 IFK(P2)<=0THENK(P2)=0:V=V+1
158 IFPEEK(56320)=111THEN185
159 SYS1701:GOTO117
160 IFEP(P2)=0THENMO(P2)=5:SV(P2)=5
161 LE(P2)=EL:SO(P2)=ES:BO(P2)=EB:K(P2)=EK:MO(P1)=MO(P1)+1:IFMO(P1)>10THENMO(P1)=10
162 MO(P2)=MO(P1):SV(P1)=SV(P1)+1:IFSV(P1)>10THENSV(P1)=10
163 IFEP(P2)=0THEN166
164 IFZP(EP(P2))=1THENKO(SP)=KO(SP)+KO(EP(P2))
165 KO(EP(P2))=KO(EP(P2))-X:SV(P2)=SV(P2)-1:IFSV(P2)<0THENSV(P2)=0
166 GB(P2)=GB(P2)-INT(RND(O)*3+1):IFGB(P2)<0THENGB(P2)=0
167 BL(P2)=EL:BS(P2)=ES:BB(P2)=EB:BK(P2)=EK:ZP(SP)=ZP(SP)+1:IS(P2)=IS(P2)-INT(RND(O)*3+1):IFIS(P2)<0THENIS(P2)=0
168 SYS1624:IFP2=HP(EP(P2))THENP=P2:GOSUB355:GOTO170
169 ZP(EP(P2))=ZP(EP(P2))-1:X=INT(KO(EP(P2))/ZP(EP(P2))):KO(SP)=KO(SP)+X
170 EP(P2)=SP:SYS1966:GOTO8
171 MO(P1)=MO(P1)-2:IFMO(P1)<0THENMO(P1)=0
172 LE(P1)=LE(P1)+EL:SO(P1)=SO(P1)+ES:BO(P1)=BO(P1)+EB:K(P1)=K(P1)+EK:SV(HP(EP(P1)))=SV(HP(EP(P1)))-1:IFSV(HP(EP(P1)))<0THENSV(HP(EP(P1)))=0
173 BL(P1)=BL(P1)+EL:BS(P1)=BS(P1)+ES:BB(P1)=BB(P1)+EB:BK(P1)=BK(P1)+EK:POKE53272,48:POKE53265,PEEK(53265)AND223:PRINT"[147]":SYS1966
174 GOTO29:GOTO8
175 IFPEEK(250)+8>255THENPOKE251,PEEK(251)+1:POKE250,PEEK(250)+8-256:RETURN
176 POKE250,PEEK(250)+8:RETURN
177 J$="J":PRINT:PRINT"  WOLLEN SIE EINEN SEHER NACH DEM":PRINT"  SCHLACHTENGL]CK BEFRAGEN ? ";J$;:GOSUB408:IFJ$="N"THEN107
178 GOSUB394:F$="SEHER.HR":GOSUB396:SYS1400,"SEHER.HR",57344:SYS1400,"SEHER.CO",51200:POKE53272,56:POKE53265,PEEK(53265)OR32:SYS1200:WAIT56320,16,16:SYS1624:PRINT:PRINT:PRINT"  DER SEHER VERLANGTE 10000 AUREI.":KP(SP)=KP(SP)-10000:PRINT"  ER SAGTE :":I=INT(4*RND(0)+1):PRINT" ";WS$(I);"!"
179 GOSUB394:F$="KARTE2":GOSUB396:SYS1400,"KARTE2",57344:WAIT56320,16,16:GOTO107
180 PRINT"":PRINT"IN WELCHER PROVINZ WOLLEN SIE ":PRINT" KATAPULTE BAUEN ?";:GOSUB423:GOTO53
181 IFPEEK(56320)=126ANDA=2THENA=1:PRINT"[145][145] _":PRINT"   ":GOSUB393
182 IFPEEK(56320)=125ANDA=1THENA=2:PRINT"[145][145]  ":PRINT" _ ":GOSUB393
183 IFPEEK(56320)=111THENGOSUB393:GOTO45
184 GOTO181
185 IFEL<=0THENEL=0
186 IFES<=0THENES=0
187 IFEB<=0THENEB=0
188 IFEK<=0THENEK=0
189 IFLE(P2)<=0THENLE(P2)=0
190 IFSO(P2)<=0THENSO(P2)=0
191 IFBO(P2)<=0THENBO(P2)=0
192 IFK(P2)<=0THENK(P2)=0
193 GOTO171
194 SYS1624:SYS1258,54784,49664,6:SYS1464,56832
195 PRINT"[147]":POKE53281,1:POKE53280,6:PRINT"[144]";:IFPP=0THEN16
196 PRINT"[147]":SYS1200:PRINT"  DEN STATTHALTER":PRINT"  WELCHER PROVINZ ":PRINT"  M\CHTEN SIE ZU":PRINT"  SICH BITTEN ?":PRINT"":GOSUB423
197 SYS1200:PRINT"":PRINT"  DER STATTHALTER ":PRINT"  BRINGT IHNEN":PRINT"  INFORMATIONEN UND":PRINT"  ERWARTET IHRE ":PRINT"  INSTRUKTIONEN !":PRINT"  INNENPOLITIK":PRINT"  AUSSENHANDEL":PRINT"  WIRTSCHAFT":PRINT"  MONATS]BERSICHT":PRINT"  ANDERE PROVINZ":PRINT" _^MENUE":PRINT"  CAESAR ";N$(SP)
198 PRINT"  KAPITAL";KP(SP);"AUREI":PRINT"[145][145][145][145][145][145][145]":I=16:J=11:GOSUB449:A=PEEK(214)-10:ONAGOTO199,230,217,290,195,8
199 PRINT"[147]  ERN[HRUNG DES P\BELS":PRINT"  STEUERSATZ [NDERN":PRINT"  STIMMUNG IN EIGENER PROVINZ":PRINT"  STIMMUNG IN FREMDER PROVINZ":PRINT" _^MENUE":I=7:J=3:GOSUB449:A=PEEK(214)-2:ONAGOTO200,206,209,213,197
200 PRINT"":PRINT"  IN DIESER PROVINZ LEBEN";PO(P)"":PRINT"  ERN[HRUNGSBED]RFTIGE !":X$=STR$(PO(P)):X=LEN(X$):FORI=XTO1STEP-1:SU$(I)=MID$(X$,X+1-I,1):SL(I)=VAL(SU$(I)):IFSU$(I)=""ORSU$(I)=" "THENSU$(I)="0":SL(I)=0
201 NEXT:TS=33:L=1:SL=0:PRINT"  JEDER BEN\TIGT EINEN SCHEFFEL KORN ":PRINT"  IM MONAT ! ":PRINT:PRINT"  BESTIMMEN SIE DIE MENGE,":PRINT"  DIE AUSGEGEBEN WERDEN SOLL:";TAB(29);"00000":PRINT"[145]";TAB(35-X);RIGHT$(X$,X-1):GOSUB399:GOTO204
202 IFPEEK(56320)=111THEN199
203 GOTO202
204 IFSL>KO(SP)THENPRINT" SO VIEL KORN HABEN SIE NICHT VORR[TIG !":GOTO202
205 KO(SP)=KO(SP)-SL:BN(P)=BN(P)+SL:PP=1:GOTO199
206 PRINT"":PRINT"  DER STEUERSATZ IN DIESER PROVINZ ":PRINT"  BETR[GT";SN(P);"% !":J$="J":PRINT"  WOLLEN SIE DIES [NDERN ? ";J$;:GOSUB408:IFJ$="N"THEN199
207 PRINT:PRINT:PRINT"  GEBEN SIE DEN NEUEN ":PRINT"  STEUERSATZ AN ";:GOSUB398:IFSL>100THENPRINT"  UNM\GLICH !!":GOTO202
208 SN(P)=SL:GOTO199
209 PRINT"  DIE STIMMUNG IN DIESER PROVINZ IST":PRINT"  ";MO$(SV(P));" !":PRINT:J$="J":PRINT"  WOLLEN SIE PROPAGANDA ( 10000 AUREI )":PRINT"    BETREIBEN ?";J$;:GOSUB408:IFJ$="N"THEN199
210 IF10000>KP(SP)THENPRINT:PRINT:PRINT"  ZUWENIG GELD !!":GOTO202
211 KP(SP)=KP(SP)-10000:SV(P)=SV(P)+1:IFSV(P)>10THENSV(P)=10
212 GOTO199
213 PRINT"  IN WELCHER PROVINZ DER FEINDE WOLLEN":A=P:PRINT"   SIE DAS VOLK AUFWIEGELN ?":GOSUB436:PRINT:PRINT"  WOLLEN SIE IN DIESER PROVINZ PROPA-":J$="J":I=P:P=A:PRINT"  GANDA BETREIBEN ( 20000 AUREI ) ? ";J$;:GOSUB408:IFJ$="N"THEN199
214 IFKP(SP)<20000THENPRINT:PRINT:PRINT"  ZUWENIG GELD !!":GOTO202
215 KP(SP)=KP(SP)-20000:SV(I)=SV(I)-1:IFSV(I)<0THENSV(I)=0
216 GOTO199
217 PRINT"[147]              WIRTSCHAFT":PRINT"  BAUERNH\FE ANLEGEN":PRINT"  BERGWERKE ERRICHTEN":PRINT"  INFRASTRUKTUR VERBESSERN":PRINT"  KREDIT AUFNEHMEN":PRINT" _^MENUE":PRINT"    KAPITAL";KP(SP);"AUREI";"[145][145]":I=9:J=5:GOSUB449:A=PEEK(214)-4:ONAGOTO218,220,222,226,197
218 PRINT"  IN DIESER PROVINZ BESITZEN SIE":PRINT"  BEREITS";ZG(P);"BAUERNH\FE .":PRINT:PRINT"  DAS ANLEGEN EINES HOFES KOSTET ":PRINT"  500 AUREI !":PRINT"  WIE VIELE BAUERNH\FE WOLLEN SIE":PRINT"  ANLEGEN ";:GOSUB398:IFSL*500>KP(SP)THENPRINT:PRINT"  ZUWENIG GELD !!":GOTO229
219 KP(SP)=KP(SP)-SL*500:ZG(P)=ZG(P)+SL:GOTO217
220 PRINT"  IN DIESER PROVINZ BESITZEN SIE":PRINT"  BEREITS";ZB(P);"BERGWERKE .":PRINT:PRINT"  DAS ANLEGEN EINES BERGWERKS KOSTET ":PRINT"  6000 AUREI !":PRINT"  WIE VIELE BERGWERKE WOLLEN SIE":PRINT"  ERRICHTEN ";:GOSUB398:IFSL*6000>KP(SP)THENPRINT:PRINT"  ZUWENIG GELD !!":GOTO229
221 KP(SP)=KP(SP)-SL*6000:ZB(P)=ZB(P)+SL:GOTO217
222 PRINT"  DIE INFRASTRUKTUR DIESER PROVINZ IST":PRINT"  ";GB$(IS(P)):PRINT:PRINT"  WOLLEN SIE DIE INFRASTRUKTUR ":J$="J":PRINT"  VERBESSERN (5000 AUREI) ? ";J$;:GOSUB408:IFJ$="N"THEN217
223 IFKP(SP)<5000THENPRINT:PRINT"  ZU WENIG GELD !!":GOTO229
224 KP(SP)=KP(SP)-5000:IS(P)=IS(P)+1:IFIS(P)>10THENIS(P)=10
225 GOTO217
226 PRINT"  SIE BITTEN EINEN REICHEN KAUFMANN UM":PRINT"  EIN DARLEHEN.":PRINT"  WIEVIEL AUREI WOLLEN SIE SICH ":PRINT"   BORGEN ?";:GOSUB398:IFSC(SP)+SL>10000*ZP(SP)THENPRINT:PRINT"  DER KAUFMANN GIBT IHNEN NICHTS MEHR !"
227 IFSC(SP)+SL>10000*ZP(SP)THEN229
228 SC(SP)=SC(SP)+SL:KP(SP)=KP(SP)+SL:GOTO217
229 WAIT56320,16,16:GOTO217
230 PRINT"[147]              AUSSENHANDEL":PRINT"  KORN VERKAUFEN";TAB(19);"PREIS";INT(9*KP)/10;"/100 SCH.":PRINT"  KORN KAUFEN";TAB(19);"PREIS";INT(11*KP)/10;"/100 SCH.":PRINT"  ERZE VERKAUFEN";TAB(19);"PREIS";INT(MP*9)/10;"/ZENTNER"
231 PRINT"  ERZE KAUFEN";TAB(19);"PREIS";INT(MP*11)/10"/ZENTNER":PRINT"  ANDEREN KAISER UNTERST]TZEN":PRINT" _^MENUE":PRINT"  KORNVORRAT";KO(SP);"SCHEFFEL":PRINT"  ERZVORRAT";ER(SP);"ZENTNER":PRINT"  KAPITAL";KP(SP);"AUREI":PRINT"[145][145][145][145][145]";:I=12:J=7:GOSUB449
232 A=PEEK(214)-6:ONAGOTO234,236,238,240,242,197
233 WAIT56320,16,16:GOTO230
234 PRINT"":PRINT"  WIEVIEL KORN WOLLEN SIE":PRINT"  VERKAUFEN ?";:GOSUB398:IFSL>KO(SP)THENPRINT"  UNM\GLICH !!":GOTO233
235 KO(SP)=KO(SP)-SL:KP(SP)=INT(KP(SP)+INT(9*KP)/1000*SL):GOTO230
236 PRINT"":PRINT"  WIEVIEL KORN WOLLEN SIE":PRINT"  KAUFEN ?";:GOSUB398:IFSL*INT(11*KP)/1000>KP(SP)THENPRINT"  UNM\GLICH !!":GOTO233
237 KO(SP)=KO(SP)+SL:KP(SP)=INT(KP(SP)-INT(11*KP)/1000*SL):GOTO230
238 PRINT"":PRINT"  WIEVIEL ERZ WOLLEN SIE":PRINT"  VERKAUFEN ?";:GOSUB398:IFSL>ER(SP)THENPRINT"  UNM\GLICH !!":GOTO233
239 ER(SP)=ER(SP)-SL:KP(SP)=INT(KP(SP)+INT(9*MP)/10*SL):GOTO230
240 PRINT"":PRINT"  WIEVIEL ERZ WOLLEN SIE":PRINT"  KAUFEN ?";:GOSUB398:IFSL*INT(11*MP)/10>KP(SP)THENPRINT"  UNM\GLICH !!":GOTO233
241 ER(SP)=ER(SP)+SL:KP(SP)=INT(KP(SP)-INT(11*MP)/10*SL):GOTO230
242 PRINT"[147]       HANDEL MIT MITSPIELERN":PRINT:PRINT:PRINT"  KORN SCHENKEN":PRINT"  ERZ SCHENKEN":PRINT"  GELD SCHENKEN":PRINT"  S\LDNER SCHENKEN":PRINT"  KATAPULTE SCHENKEN":PRINT"  BOGENSCH]TZEN SCHENKEN":PRINT" _^MENUE":I=12:J=6:GOSUB449:GOTO244
243 WAIT56320,16,16:GOTO242
244 A=PEEK(214)-5:IFA=7THEN230
245 PRINT"[147]  WELCHEN SPIELER WOLLEN SIE ":I=1:IFSP=1THENI=2
246 PRINT"  BESCHENKEN ? CAESAR ";N$(I);"         "
247 IFPEEK(56320)=125THENI=I-1:GOSUB393:GOTO251
248 IFPEEK(56320)=126THENI=I+1:GOSUB393:GOTO251
249 IFPEEK(56320)=111THENGOSUB393:GOTO256
250 GOTO247
251 IFI>4THENI=1
252 IFI<1THENI=4
253 IFI=SPTHENI=I+1:GOTO251
254 IFEP(HP(I))<>ITHENI=I+1:GOTO251
255 PRINT"[145]";:GOTO246
256 GOSUB263:ONAGOTO257,259,261,281,287,284,197
257 PRINT"  WIEVIEL KORN WOLLEN SIE IHM":PRINT"  SCHENKEN ?";:GOSUB398:IFSL>KO(SP)THENPRINT"  SOVIEL HABEN SIE NICHT !!":GOTO243
258 KO(SP)=KO(SP)-SL:KO(I)=KO(I)+SL:GOTO242
259 PRINT"  WIEVIEL ERZ WOLLEN SIE IHM":PRINT"  SCHENKEN ?";:GOSUB398:IFSL>ER(SP)THENPRINT"  SOVIEL HABEN SIE NICHT !!":GOTO243
260 ER(SP)=ER(SP)-SL:ER(I)=ER(I)+SL:GOTO242
261 PRINT"  WIEVIEL GELD WOLLEN SIE IHM":PRINT"  SCHENKEN ?";:GOSUB398:IFSL>KP(SP)THENPRINT"  SOVIEL HABEN SIE NICHT !!":GOTO243
262 KP(SP)=KP(SP)-SL:KP(I)=KP(I)+SL:GOTO242
263 P=1:PRINT"  F]R WELCHE PROVINZ WOLLEN SIE IHM":PRINT"  ETWAS SCHENKEN ?"
264 IFEP(R)<>ITHENR=R+1:GOTO266
265 GOTO268
266 IFR>16THENR=1
267 GOTO264
268 PRINT"  ";NP$(R);" ?";:FORT=1TO30-LEN(NP$(R)):PRINT" ";:NEXT:PRINT"[145]"
269 IFPEEK(56320)=125THENR=R-1:GOSUB393:GOTO273
270 IFPEEK(56320)=126THENR=R+1:GOSUB393:GOTO273
271 IFPEEK(56320)=111THENGOSUB393:RETURN
272 GOTO269
273 IFR>16THENR=1
274 IFR<1THENR=16
275 GOTO264
276 X=1:I=0
277 IFP=A(X,R)THENRETURN
278 IFA(X,R)=0THEN280
279 X=X+1:GOTO277
280 I=1.1:RETURN
281 GOSUB276:IFI=1.1THEN242
282 PRINT"  WIE VIELE S\LDNER WOLLEN SIE IHM":PRINT"  SCHENKEN ?";:GOSUB398:IFSL>SO(P)THENPRINT"  SO VIELE HABEN SIE HIER NICHT !":GOTO243
283 SO(P)=SO(P)-SL:SO(R)=SO(R)+SL:BS(R)=BS(R)+SL:GOTO242
284 GOSUB276:IFI=1.1THEN242
285 PRINT"  WIE VIELE SCH]TZEN WOLLEN SIE IHM":PRINT"  SCHENKEN ?";:GOSUB398:IFSL>BO(P)THENPRINT"  SO VIELE HABEN SIE HIER NICHT !":GOTO243
286 BO(P)=BO(P)-SL:BO(R)=BO(R)+SL:BB(R)=BB(R)+SL:GOTO242
287 GOSUB276:IFI=1.1THEN242
288 PRINT"  WIE VIELE KATAPULTE WOLLEN SIE IHM":PRINT"  SCHENKEN ?";:GOSUB398:IFSL>K(P)THENPRINT"  SO VIELE HABEN SIE HIER NICHT !":GOTO243
289 K(P)=K(P)-SL:K(R)=K(R)+SL:BK(R)=BK(R)+SL:GOTO242
290 PRINT"[147]  MONATS]BERSICHT DER PROVINZ":PRINT"  ";NP$(P);TAB(26);M$(M);JA:PRINT" AUSGABEN F]R GUTSH\FE";TAB(25);AG(P):PRINT" AUSGABEN F]R BERGWERKE";TAB(25);AB(P):PRINT" MILIT[RAUSGABEN";TAB(25);MA(P):PRINT:PRINT" EINNAHMEN DER BERGWERKE";TAB(25);IB(P):PRINT" STEUEREINNAHMEN";TAB(25);SE(P)
291 PRINT:PRINT" ZAHL DER GUTSH\FE";TAB(25);ZG(P):PRINT" ZAHL DER BERGWERKE";TAB(25);ZB(P):PRINT" STIMMUNG IM VOLK:";TAB(26);MO$(SV(P)):PRINT" STIMMUNG IM MILIT[R:";TAB(26);MO$(MO(P)):PRINT" ABGEGEBENES KORN:";TAB(25);BN(P):PRINT" ZAHL DES PROLETARIATS";TAB(25);PO(P):PRINT" BEV\LKERUNG";TAB(25);BV(P)
292 PRINT" STEUERSATZ";TAB(25);SN(P);"%":PRINT" PROVINZNUMMER";TAB(25);P:WAIT56320,16,16:GOTO197
293 PRINT"[147]  DA IN DIESER PROVINZ KEINE TRUPPEN":PRINT"  STATIONIERT SIND, K\NNEN SIE MIT ":PRINT"  IHREN SOLDATEN UNGEHINDERT IN DEREN":PRINT"  HAUPTSTADT EINMARSCHIEREN. ":PRINT"  DORT ERFAHREN SIE, DASS SICH DER BIS-":PRINT"  HERIGE STATTHALTER BEREITS ABGESETZT"
294 PRINT"  HAT. SIE BESTIMMEN EINEN NEUEN STATT-":PRINT"  HALTER, DER DIE PROVINZ VON NUN AN":PRINT"  IN IHREM SINNE VERWALTEN WIRD.":WAIT56320,16,16:SYS1966:GOTO160
295 FORP=1TO16:IFEP(P)<>SPTHEN311
296 XX=BN(P)/PO(P):IFXX>=1THENSV(P)=INT(SV(P)*1.44*(LOG((BN(P)+1)/PO(P))+1)+.5):ZM(P)=0
297 IFXX<1THENSV(P)=INT(-1*SV(P)/(LOG(XX+.001)-1))
298 KR(P)=KR(P)-1:IFKR(P)=0THENKR(P)=10:MO(P)=MO(P)-1
299 IFMO(P)<0THENMO(P)=0
300 IFXX>1THENPO(P)=INT((BN(P)/PO(P)/5+1)*PO(P)*(RND(0)/5+.9))
301 IFXX<1THENPO(P)=INT(BN(P)+RND(0)*2000-1000)
302 SV(P)=INT(SV(P)/(SN(P)+1)*16):PO(P)=INT(PO(P)+RND(0)*200):BV(P)=INT(BV(P)*(RND(0)*.1+.9)+PO(P)+200*SV(P)+20*ZG(P)):IFPO(P)<0.05*BV(P)THENSV(P)=SV(P)-2
303 IFMO(P)=1THENPRINT"  UNRUHEN IM MILIT[R IN ":PRINT"   ";NP$(P);" !"
304 IFSV(P)<0THENSV(P)=0
305 IFMO(P)=0THENPRINT"  MILIT[RPUTSCH IN ":PRINT"   ";NP$(P);" !!!":GOTO342
306 IFSV(P)=1THENPRINT"  UNRUHEN IN ";NP$(P);" !"
307 IFSV(P)=0THENPRINT"  VOLKSAUFSTAND IN ":PRINT"   ";NP$(P);" !!!":GOTO338
308 IFSV(P)>10THENSV(P)=10
309 IFPO(P)<100THENPO(P)=100
310 IFPO(P)>99999THENPO(P)=99999
311 NEXT:MP=MP*(RND(0)/5+.9):KP=KP*(RND(0)/10+1):IFM=8THENKP=(RND(0)/5+.9)*2:GOTO360
312 FORP=1TO16:IFEP(P)<>SPTHEN315
313 RE(P)=0:Z=GR(P)/BV(P):AB(P)=500*ZB(P):AG(P)=10*ZG(P):IB(P)=INT(10*SQR(BW(P))*ZB(P)/(RND(0)*1.5+.5)+ZB(P)*IS(P))-INT(80*Z*ZB(P)):SE(P)=INT(SN(P)*BV(P)/(RND(0)*0.5+.5)/200)-INT(30000*Z):IFSE(P)<0THENSE(P)=0
314 MA(P)=INT(.2*LE(P)+1.5*SO(P)+2*BO(P)):KP(SP)=KP(SP)-MA(P)-AB(P)-AG(P)+SE(P):ER(SP)=ER(SP)+IB(P)
315 NEXT:KO(SP)=INT(KO(SP)*(RND(0)*.1+.85)):I=INT(RND(0)*50+1):IFI>8THEN320
316 GOSUB394:IFEP(HP(SP))<>SPTHEN320
317 P=INT(RND(0)*16+1):IFEP(P)<>SPTHEN317
318 PRINT" IN DER PROVINZ ";NP$(P):PRINT" IST FOLGENDES PASSIERT :":PRINT:FI$="EREIG"+STR$(I):OPEN2,8,2,FI$+",S,R":INPUT#2,AZ:FORT=1TO2*AZ-1:GET#2,A$:IFA$=CHR$(13)THENNEXT
319 PRINTA$;:NEXT:CLOSE2:ONIGOTO329,331,332,333,334,335,336,337
320 SP=SP+1:IFSP>4THENSP=1:M=M+1:FORI=1TO16:BL(I)=0:BS(I)=0:BK(I)=0:BB(I)=0:NEXT
321 IFEP(HP(SP))<>SPOREX(SP)=0THEN320
322 FORI=1TO16:IFEP(I)=0THENLE(I)=LE(I)+100:SV(I)=8:MO(I)=8
323 NEXT:FORI=1TO16:IFEP(I)=SPTHENBN(I)=0
324 NEXT:IFSC(SP)>0THENKP(SP)=KP(SP)-3000:SC(SP)=SC(SP)-2000
325 IFSC(SP)<0THENSC(SP)=0
326 IFM>12THENM=1:JA=JA+1:IFJA=324THEN391
327 IFZS=1THEN388
328 GOSUB394:F$=HZ$(SP):GOSUB396:SYS1400,HS$(SP),49664:SYS1258,49664,56832,2:SYS1400,HZ$(SP),49664:SYS1258,49664,54784,6:PP=0:PRINT:PRINT"";TAB(12);"KNOPF DR]CKEN !":WAIT56320,16,16:GOSUB393:GOTO8
329 GB(P)=GB(P)-2:IFGB(P)<0THENGB(P)=0
330 ZB(P)=INT(ZB(P)*.8):ZG(P)=INT(ZG(P)*.9):GOTO320
331 BV(P)=INT(BV(P)*.85):GOTO320
332 ZB(P)=ZB(P)-1:IFZB(P)<0THENZB(P)=0:GOTO320
333 ZG(P)=INT(ZG(P)*.95):GOTO320
334 KP(SP)=KP(SP)+10000:GOTO320
335 KP(SP)=KP(SP)+7500:GOTO320
336 KP(SP)=KP(SP)+15000:GOTO320
337 KP(SP)=KP(SP)+5000:GOTO320
338 PRINT" DAS VOLK (DER P\BEL) HAT DEN PALAST":PRINT" GEST]RMT UND IHRE VERWALTER UMGE-":PRINT" BRACHT !":T=INT(KO(SP)/ZP(SP)):S=INT(KP(SP)/ZP(SP)):KO(SP)=KO(SP)-T:KP(SP)=KP(SP)-S:PRINT" DIE KORNSPEICHER WURDEN GEPL]NDERT."
339 PRINT" INSGESAMT WURDEN";T;"SCHEFFEL":PRINT" GESTOHLEN !":PRINT" AUS IHRER KASSE WURDEN";S;"AUREI":PRINT" ENTWENDET !":ZP(SP)=ZP(SP)-1:PRINT" DIE PROVINZ HAT SICH F]R UNABH[NGIG":PRINT" ERKL[RT ,UND AUCH DAS MILIT[R ":PRINT" IST ZUR NEUEN REGIERUNG ]BERGE-":PRINT" LAUFEN !!"
340 WAIT56320,16,16:GOSUB393:IFP=HP(SP)THENGOSUB355
341 EP(P)=0:LE(P)=10000:MO(P)=10:SV(P)=10:PO(P)=INT(0.05*BV(P)):PRINT"[147]":GOTO308
342 PRINT" DAS MILIT[R HAT DIE MACHT IN IHRER":H=0:PRINT" PROVINZ ]BERNOMMEN UND DEN OBERSTEN":PRINT" BEFEHLSHABER ZUM NEUEN HERRSCHER AUS-":PRINT" GERUFEN. DIESER HAT ERKL[RT, DASS ER":PRINT" DEMJENIGEN KAISER DIE PROVINZ ]BER-"
343 PRINT" L[SST, DER IHM UND SEINER ARMEE DAS ":PRINT" MEISTE ZAHLT !":WAIT56320,16,16:GOSUB393:I=1
344 IFEP(HP(I))<>IOREX(I)=0THENI=I+1:GOTO344
345 T$=CHR$(34):PRINT"[147] ";T$;"CAESAR ";N$(I);",":PRINT" MINDESTGEBOT SIND 5000 AUREI,":PRINT" SONST BEKOMMT DER ALTE EIGENT]MER":PRINT" DIE PROVINZ ZUR]CK !";T$:S=5000
346 PRINT" CAESAR ";N$(I);",":J$="J":IFH=ITHEN351
347 PRINT"  BIETEN SIE";S;"?";J$;:GOSUB408:PRINT:IFJ$="J"ANDKP(I)>=STHENH=I:HG=S:S=S+5000
348 I=I+1:IFI>4THENI=1:PRINT"[147]":IFH=0THEN306
349 IFEP(HP(I))<>ITHEN348
350 GOTO346
351 PRINT" SIE HABEN DIE PROVINZ ERSTEIGERT !":X=I:WAIT56320,16,16:IFP=HP(SP)THENGOSUB355
352 ZP(X)=ZP(X)+1:ZP(SP)=ZP(SP)-1:EP(P)=X:KP(X)=KP(X)-HG:MO(P)=5
353 IFPEEK(56320)<>111THEN353
354 PRINT"[147]":GOTO306
355 PRINT"[147] CAESAR ";N$(EP(P));",":PRINT:PRINT"  HIERMIT HABEN SIE IHRE HAUPTPROVINZ ":PRINT"  VERLOREN. DESHALB IST DAS SPIEL F]R":PRINT"  SIE NUN ZUENDE !":ZS=ZS-1:IFEP(P)<>SPTHEN378
356 PRINT:PRINT"  IHRE ANDEREN PROVINZEN BLEIBEN SELB- ":PRINT"  ST[NDIG.":EX(EP(P))=0:IFZS=1THENEP(P)=0:GOTO388
357 FORI=1TO16:IFI=PTHEN359
358 IFEP(I)=EP(P)THENEP(I)=0:LE(I)=10000:SV(I)=10:MO(I)=7:PO(I)=INT(.05*BV(I))
359 NEXTI:WAIT56320,16,16:RETURN
360 PRINT"[147]  IN DIESEM MONAT WIRD GEERNTET !":K=0:FORP=1TO16:IFEP(P)<>SPTHEN362
361 K=K+30*INT(SQR(FB(P))*ZG(P)*(RND(0)*1.2+1))
362 NEXT:K=K*10:KO(SP)=KO(SP)+K:PRINT"  IN IHREN PROVINZEN HABEN SIE INSGE-":PRINT"  SAMT";K;" SCHEFFEL KORN GEERNTET !":WAIT56320,16,16:PRINT"[147]":GOTO312
363 SYS1624:POKE53280,6:POKE53281,1:PRINT"[144][147]  ]BERSICHT/SPIELSTAND":PRINT"  SPIELSTAND":PRINT"  SPIEL LADEN":PRINT"  SPIEL SPEICHERN":PRINT" _^MENUE":I=9:J=6:GOSUB449:A=PEEK(214)-5:ONAGOTO364,370,368,8
364 FORI=1TO4:IFEP(HP(I))<>ITHEN367
365 PRINT"[147] SPIELSTAND IM ";M$(M);" DES JAHRES";JA:PRINT"  CAESAR ";N$(I):PRINT" KAPITAL";TAB(15);KP(I);" AUREI":PRINT" ZAHL D. PROV.";TAB(15);ZP(I):PRINT" KREDTITE";TAB(15);SC(I);" AUREI":PRINT" ERZMENGE";TAB(15);ER(I);" ZENTNER":PRINT" KORNVORRAT";TAB(15);KO(I);" SCHEFFEL"
366 WAIT56320,16,16:GOSUB393
367 NEXT:GOTO363
368 FORP=1TO10:NEXT:FI$="":PRINT" FILENAME";:GOSUB413:GOSUB394:OPEN1,8,15,"S:"+FI$:CLOSE1:OPEN2,8,2,FI$+",S,W":PRINT#2,M:FORP=1TO16:PRINT#2,BV(P):PRINT#2,LE(P):PRINT#2,SO(P):PRINT#2,BO(P):PRINT#2,K(P):PRINT#2,GB(P):PRINT#2,EP(P):PRINT#2,BN(P):PRINT#2,SV(P):PRINT#2,RE(P):PRINT#2,ZB(P):PRINT#2,ZG(P):PRINT#2,BL(P):PRINT#2,BS(P):PRINT#2,BB(P):PRINT#2,BK(P)
369 PRINT#2,PO(P):PRINT#2,SN(P):PRINT#2,IS(P):PRINT#2,KR(P):PRINT#2,GR(P):PRINT#2,ZM(P):PRINT#2,IB(P):PRINT#2,AB(P):PRINT#2,AG(P):PRINT#2,SE(P):PRINT#2,MA(P):NEXT:FORI=1TO4:PRINT#2,KO(I):PRINT#2,SC(I):PRINT#2,ZP(I):PRINT#2,ER(I):PRINT#2,KP(I):PRINT#2,EX(I):PRINT#2,N$(I):NEXT:PRINT#2,JA:PRINT#2,SP:PRINT#2,KP:PRINT#2,MP:PRINT#2,ZS:PRINT#2,PP:CLOSE2:GOTO363
370 FORP=1TO10:NEXT:FI$="":PRINT" FILENAME";:GOSUB413:GOSUB394:OPEN2,8,2,FI$+",S,R":INPUT#2,M:IFST<>0THENCLOSE2:PRINT:PRINT" DATEI NICHT AUF DISKETTE !":GOTO375
371 FORP=1TO16:INPUT#2,BV(P):INPUT#2,LE(P):INPUT#2,SO(P):INPUT#2,BO(P):INPUT#2,K(P):INPUT#2,GB(P):INPUT#2,EP(P):INPUT#2,BN(P):INPUT#2,SV(P):INPUT#2,RE(P):INPUT#2,ZB(P):INPUT#2,ZG(P):INPUT#2,BL(P):INPUT#2,BS(P):INPUT#2,BB(P):INPUT#2,BK(P):INPUT#2,PO(P):INPUT#2,SN(P):INPUT#2,IS(P):INPUT#2,KR(P):INPUT#2,GR(P)
372 INPUT#2,ZM(P):INPUT#2,IB(P):INPUT#2,AB(P):INPUT#2,AG(P):INPUT#2,SE(P):INPUT#2,MA(P):NEXT:FORI=1TO4:INPUT#2,KO(I):INPUT#2,SC(I):INPUT#2,ZP(I):INPUT#2,ER(I):INPUT#2,KP(I):INPUT#2,EX(I):INPUT#2,N$(I):NEXT:INPUT#2,JA:INPUT#2,SP:INPUT#2,KP:INPUT#2,MP:INPUT#2,ZS:INPUT#2,PP:CLOSE2:PRINT:PRINT" OK"
373 PRINT:PRINT" SPIELDISKETTE EINLEGEN !":WAIT56320,16,16:OPEN2,8,2,"REMIS,P,R":GET#2,I$:IFST<>0THENCLOSE2:GOTO373
374 CLOSE2:SYS1400,HS$(SP),49664:SYS1258,49664,56832,2:SYS1400,HZ$(SP),49664:SYS1258,49664,54784,6:GOTO363
375 WAIT56320,16,16:GOTO363
376 SYS1624:POKE53281,1:J$="N":PRINTTAB(8);"ZUG WIRKLICH BEENDEN ? ";J$;:GOSUB408:IFJ$="J"THENPRINT"[147]":GOTO295
377 GOTO8
378 PRINT"[147] IN IHRER PROVINZ BEFINDEN SICH":PRINT"  ";LE(P1);" LEGION[RE !":KR(P1)=10:PRINT"  ";SO(P1);" S\LDNER !":PRINT"  ";BO(P1);" BOGENSCH]TZEN !":PRINT"  ";K(P1);" KATAPULTE !":PRINT:PRINT" WIEVIELE LEGION[RE WOLLEN SIE":PRINT" MITNEHMEN ?";:GOSUB398
379 IFSL>LE(P1)THENPRINT" UNM\GLICH":GOTO77
380 IFSL>LE(P1)-BL(P1)THENPRINT" UNM\GLICH":GOTO77
381 EL=SL:PRINT" WIEVIELE S\LDNER WOLLEN SIE ":PRINT" MITNEHMEN ?";:GOSUB398:IFSL>SO(P1)THENPRINT" UNM\GLICH ":GOTO77
382 IFSL>SO(P1)-BS(P1)THENPRINT" UNM\GLICH":GOTO77
383 ES=SL:PRINT" WIEVIELE SCH]TZEN WOLLEN SIE ":PRINT" MITNEHMEN ?";:GOSUB398:IFSL>BO(P1)THENPRINT" UNM\GLICH ":GOTO77
384 IFSL>BO(P1)-BB(P1)THENPRINT" UNM\GLICH":GOTO77
385 EB=SL:PRINT" WIEVIELE KATAPULTE WOLLEN SIE ":PRINT" MITNEHMEN ?";:GOSUB398:IFSL>K(P1)THENPRINT" UNM\GLICH ":GOTO77
386 IFSL>K(P1)-BK(P1)THENPRINT" UNM\GLICH":GOTO77
387 EK=SL:BK(P1)=BK(P1)+EK:BL(P1)=BL(P1)+EL:BB(P1)=BB(P1)+EB:BS(P1)=BS(P1)+ES:RETURN
388 FI$="SIEGER":FORI=1TO4:IFEP(HP(I))=ITHENSP=I:GOTO390
389 NEXT
390 GOSUB394:OPEN1,8,15,"S:NASIEG":CLOSE1:OPEN2,8,2,"NASIEG,S,W":PRINT#2,N$(SP):CLOSE2:GOTO392
391 FI$="REMIS"
392 GOSUB394:POKE53280,0:POKE53281,0:A$=CHR$(34):PRINT"[147][144]L[207]";A$;FI$;A$;",8,1":PRINT"RUN":POKE198,3:POKE631,19:POKE632,13:POKE633,13:END
393 POKESI+24,15:POKESI+3,5:POKESI+2,250:POKESI+5,37:POKESI+6,17:POKESI,193:POKESI+1,7:POKESI+4,65:FORT=1TO75:NEXT:POKESI+4,0:RETURN
394 OPEN2,8,2:CLOSE2:IFST=0THENRETURN
395 PRINT"[147]  BITTE SCHALTEN SIE IHR LAUFWERK AN":PRINT"    UND LEGEN DIE DISKETTE EIN !":WAIT56320,16,16:GOTO394
396 OPEN2,8,2,F$+",P,R":GET#2,A$:IFST=0THENCLOSE2:RETURN
397 CLOSE2:PRINT"   LEGEN SIE DIE SPIELDISKETTE EIN  !":WAIT56320,16,16:GOTO396
398 PRINTTAB(29);"00000":TS=33:L=1:FORSS=1TO5:SU$(SS)="0":SL(SS)=0:SL=0:S=0:NEXT
399 SU$(L)=STR$(SL(L)):SU$(L)=MID$(SU$(L),2,1):PRINT"[145]";TAB(TS);SU$(L):PRINTTAB(TS-1);" # ":PRINT"[145]";:IFPEEK(56320)=111THENGOSUB393:GOTO407
400 IFPEEK(56320)=125THENSL(L)=SL(L)-1:GOSUB393
401 IFPEEK(56320)=119ANDL>1THENL=L-1:TS=TS+1:GOSUB393
402 IFPEEK(56320)=123ANDL<5THENL=L+1:TS=TS-1:GOSUB393
403 IFPEEK(56320)=126THENSL(L)=SL(L)+1:GOSUB393
404 IFSL(L)>9THENSL(L)=0
405 IFSL(L)<0THENSL(L)=9
406 GOTO399
407 FORL=1TO5:SL=SL+10^(L-1)*SL(L):NEXTL:SL=INT(SL+.5):RETURN
408 IFPEEK(56320)=126ANDJ$<>"J"THENJ$="J":PRINT"[157]";J$;:GOSUB393
409 IFPEEK(56320)=126ANDJ$<>"J"THENJ$="J":PRINT"[157]";J$;:GOSUB393
410 IFPEEK(56320)=125ANDJ$<>"N"THENJ$="N":PRINT"[157]";J$;:GOSUB393
411 IFPEEK(56320)=111THENGOSUB393:RETURN
412 GOTO409
413 X=1:PRINT"";
414 GETA$(X):IFA$(X)=""THEN414
415 IFASC(A$(X))<65ORASC(A$(X))>90THEN419
416 IFX<>16THENPRINTA$(X);:X=X+1
417 GOTO414
418 FORY=1TOX-1:FI$=FI$+A$(Y):NEXT:RETURN
419 IFASC(A$(X))=13ANDX>1THEN418
420 IFASC(A$(X))=20THENX=X-1:PRINT"[157]  [157][157]";
421 IFX<1THENX=1:PRINT"";
422 GOTO414
423 P=1:PRINT:I=1
424 IFEP(P)<>SPTHENP=P+1*I:GOTO426
425 GOTO429
426 IFP>16THENP=1
427 IFP<1THENP=16
428 GOTO424
429 PRINT"  ";NP$(P);:FORT=1TO30-LEN(NP$(P)):PRINT" ";:NEXT:PRINT"[145]":IFPEEK(56320)=125THENP=P-1:I=-1:GOSUB393:GOTO433
430 IFPEEK(56320)=126THENP=P+1:I=1:GOSUB393:GOTO433
431 IFPEEK(56320)=111THENGOSUB393:RETURN
432 GOTO429
433 IFP>16THENP=1
434 IFP<1THENP=16
435 GOTO424
436 P=1:PRINT:I=1
437 IFEP(P)=SPTHENP=P+1*I:GOTO439
438 GOTO442
439 IFP>16THENP=1
440 IFP<1THENP=16
441 GOTO437
442 PRINT"  ";NP$(P);:FORT=1TO30-LEN(NP$(P)):PRINT" ";:NEXT:PRINT"[145]":IFPEEK(56320)=125THENP=P-1:I=-1:GOSUB393:GOTO446
443 IFPEEK(56320)=126THENP=P+1:I=1:GOSUB393:GOTO446
444 IFPEEK(56320)=111THENGOSUB393:RETURN
445 GOTO442
446 IFP>16THENP=1
447 IFP<1THENP=16
448 GOTO437
449 IFPEEK(56320)=125ANDPEEK(214)<ITHENPRINT"[145]  ":PRINT" _":GOSUB393
450 IFPEEK(56320)=126ANDPEEK(214)>JTHENPRINT"[145][145] _":PRINT"  ":PRINT"[145]";:GOSUB393
451 IFPEEK(56320)=111THENGOSUB393:RETURN
452 GOTO449